Video Toaster 4.3/Video Toaster v4.3.iso/4.2/arexx/editor/oz/31-grp-vols

Text File | 1998-04-16 | 6KB | 175 lines

/* Audio-Lvls.rexx V1.3 -- Changes the audio volumes of a project in many ways, Absolute, Proportional or Relative.  Try Proportional - it maintains your mixing balance by adjusting by percentages.

-- By Aussie -  ©1995 Michael Holten


This routine allows a variety of methods to select the clips you wish to affect. (e.g. Video or audio clips, channel assignment, and audio ON or OFF)

Note: This routine operates only on clips starting at the highlighted one through to either a STOP crouton or the end of project.  Place a STOP crouton (found in Effects/Control folder) into your project, if you wish to limit this routine.
*/

call remlib('PROJECT_REXX_PORT')
call addlib('PROJECT_REXX_PORT',0)

start_loc=croutonspot()
project_end=croutonsinproject()
call croutonpick(start_loc)

current_spot=start_loc  /*was 0 */
highvol=100
progsign=" "

/* --- wait for any screen update delay --- */
call time('R')
do while (time('E')<0.5)
    end

call req_open("Group Levels - by Aussie","------------------------","Controls audio volumes in many ways.","From SELECTED icon to END (or STOP icon)")
test=req_tell("First you pick your mixing style"," "," ")
call req_close()
if test~=1 then call quit()

call req_open("Audio Levels - by Aussie","1:Absolute (force levels to = setting)","2:Proportional (adjust by % value)    ","3:Relative (adjust by +/- value)       ")
prog=req_number("1:Abs(=)  2:Prop(%)  3:Relat(+/-)",2,1,3)
call req_close()
if prog="CANCEL" then call quit()
if prog=1 then call progabs()
if prog=2 then call progprop()
if prog=3 then call progrel()
if volume="CANCEL" then call quit()

test=req_buttons("Now pick which clips to control...","11","Audio clips","Video clips")
if test="CANCEL" | test="00" then call quit()
if test="01" then cp=1
if test="10" then cp=2
if test="11" then cp=3

if cp=1 then note1="Video clips only"
if cp=2 then note1="Audio clips only"
if cp=3 then note1="Both Video & Audio clips"


test=req_buttons("Select clips set ONLY as...","1110","Channel 1 (Mono)","Channel 2 (Mono)", "Ch 1+2 (Stereo)","Audio turned OFF")
if test="CANCEL" | test="0000" then call quit()
ch1=substr(test,1,1)
ch2=substr(test,2,1)
ch3=substr(test,3,1)
ch4=substr(test,4,1)


if ch1=1 then note2="Left channel clips only"
if ch2=1 then note2="Right channel clips only"
if ch3=1 then note2="Stereo clips only"
if ch4=1 then note2="Audio OFF clips only"

if ch1+ch2+ch3+ch4>1 then do
   note2=""
   if ch1 then note2="Left "
   if ch2 then note2=note2||"Right "
   if ch3 then note2=note2||"Stereo "
   if ch4 then note2=note2||"Audio OFF"
   if ch1 & ch2 & ch3 & ch4 then note2="All clips"
   end
call req_open(,,"Proceed with settings?","This is last chance to proceed or cancel.")
test=req_tell("Proceed with changing audio levels",prognote volume progsign,"Clips: " note1,"Select: " note2)
call req_close()
if test=0 then call quit()

current_spot=start_loc /* was 0 */

do while (current_spot<project_end+1)
   call croutonpick(current_spot)
   current_spot=current_spot+1


   if croutontype()="CTRL" then do
      test=croutonname()
      test1=right(test,length(test)-lastpos("/",test))
      test3=("STOP" = upper(test1))
      if test3=1 then do
         call croutonpick(start_loc)
         call req_error(" OZ:  All Done, Stopping at STOP crouton      <<< New audio volumes set >>>")
         call quit2()
         end
      end



   if ((cp=1 | cp=3) & croutontype()="CLIP") | (cp>1 & croutontype()=" AUD") then do
      test=croutongettag(AUDIOON)
      if (ch4 & test<7) | (ch3 & test=15) | (ch2 & test=11) | (ch1 & test=7) then do
         vol1M=croutongettag(AUDIOVOLUME1)
         vol1=((vol1M/655.35)+0.5)%1
         if prog=1 then vol1=volume
         if prog=2 then vol1=(vol1*volume)/100
         if prog=3 then vol1=vol1+volume
         if vol1<0 then vol1=0
         if vol1>100 then vol1=100
         vol1=vol1*655.35
         call croutonsettag(AUDIOVOLUME1,vol1)
         vol2M=croutongettag(AUDIOVOLUME2)
         vol2=((vol2M/655.35)+0.5)%1
         if prog=1 then vol2=volume
         if prog=2 then vol2=(vol2*volume)/100
         if prog=3 then vol2=vol2+volume
         if vol2<0 then vol2=0
         if vol2>100 then vol2=100
         vol2=vol2*655.35
         call croutonsettag(AUDIOVOLUME2,vol2)
         end
      end
   end

call croutonpick(start_loc)
call req_error(" OZ:   All Done!     <<< New audio volumes are set >>>")
call remlib("PROJECT_REXX_PORT")
exit


progabs:
prognote="Absolute level:  ="
call req_open("Absolute Volume (=)","---------------------------","This routine will change all volumes","absolutely
 to equal the above level.")

volume=req_number("Make all volumes (0-100):",70,0,100)
call req_close()
return


progprop:
prognote="Percentage adjustment:  "
call req_open("Proportional Volume (%)","-------------------------------","This routine will change all volumes","proportionally
 by the above percentage.")

progsign="%"
volume=req_number("Make 100% volume (0-1000):",highvol,0,1000)
call req_close()
if volume=100 then do
   call req_tell("<<< Canceled >>>","     Because % was set to 100%","     No
 levels would be changed.")
   call quit()
   end
return


progrel:
prognote="Relative adjustment:  "
call req_open("Relative Volume (+/-)","---------------------------","This routine will change all volumes relatively","
by adding or subtracting the above value")

volume=req_number("Adjust volumes by (-100 to +100):",0,-100,100)
call req_close()
if volume>0 then prognote=prognote||"+"
if volume=0 then call quit()
return


quit:
call croutonpick(start_loc)
call req_error(" OZ:     <<< Last Operation Canceled >>>")

quit2:
call remlib("PROJECT_REXX_PORT")

exit